"Election Day" by "Amorak K. Huey"

Use American dialect and the serial comma.

Include Plurality by Emily Short.
Include clothing by Joe W Aultman.

Release along with the introductory booklet, a website, and the source text.


Part I - Custom Game Elements


Chapter One - Minor Tweaks

Section 1 - People

Section 1 - Places

To decide if (thing one - a thing) is in the same region as (thing two - a thing):
	if the location of thing one is in a region that contains a room that encloses thing two, decide yes;
	decide no.

Section 2 - Things

Size is a kind of value. The sizes are small, medium, and large. A thing has a size. A thing is usually medium.

A thing is either waterproof or water-penetrable. A thing is usually waterproof.
A thing is either soaked or dry. A thing is usually dry. A waterproof thing is never soaked.

Clothing is not waterproof.
Instead of wearing soaked clothing, say "You'll not be putting on wet clothes."

Doors are usually open.

A device is either broken or working. A device is usually working.
A device is usually switched on.

Section 3 - Actions

Putting something under is an action applying to one carried thing and one thing.
Understand "put [something] under [something]" as putting something under.

Check putting something under (this is the can't put things under other things rule):
	say "[The noun] doesn't want to go under [the second noun]." instead.

Understand "look on [a supporter]" as searching.

Section 4 - Activities

Soaking something is an activity.

Rule for soaking something:
	if the noun is waterproof, do nothing instead;
	now the noun is soaked.

Section 5 - Kinds

A shoe is a kind of thing. A shoe is wearable.

An unsearchable supporter is a kind of supporter.

Section 6 - Rules

Check an actor opening a door (this is the can't open a door from on a supporter rule):
	if the actor is supported by something, say "[if the actor is the player]You'll[otherwise][The actor] will[end if] have to get off [the holder of the actor] first." instead.

The can't open a door from on a supporter rule is listed last in the check opening rules.

Check an actor closing a door (this is the can't close a door from on a supporter rule):
	if the actor is supported by something, say "[if the actor is the player]You'll[otherwise][The actor] will[end if] have to get off [the holder of the actor] first." instead.

The can't close a door from on a supporter rule is listed last in the check closing rules.

After examining a supporter, try searching the noun.

Before searching an unsearchable supporter: if the player's command includes " in ", say "You can't look in [the noun]."

Chapter Two - Custom Kinds

Section 1 - Pluggable devices

An electrified room is a kind of room.

A pluggable device is a kind of device.
A pluggable device can be plugged in.
A pluggable device is usually plugged in.

Plugging is an action applying to one thing.
Understand "plug [something]" as plugging.
Understand "plug [something] in" as plugging.
Understand "plug in [something]" as plugging.

Check an actor plugging (this is the can't plug in if the room isn't electrified rule):
	if the location of the actor is not an electrified room, say "There are no outlets here." instead.

Check an actor plugging (this is the can't plug in something that isn't pluggable rule):
	if the noun is not a pluggable device, say "It can not be plugged in." instead.

Check an actor plugging (this is the can't plug in something that's already plugged in rule):
	if the noun is plugged in, say "It is already plugged in." instead.

Carry out an actor plugging (this is the basic plugging rule):
	now the noun is plugged in.

Report an actor plugging (this is the basic report plugging rule):
	say "[if the actor is the player]You find an outlet and plug in [the noun].[otherwise][The actor] plugs in [the noun].[end if]".

Unplugging is an action applying to one thing.
Understand "unplug [something]" as unplugging.
Understand "plug [something] out" as unplugging.

Check unplugging (this is the can't unplug something that isn't pluggable rule):
	if the noun is not a pluggable device, say "It can not be unplugged." instead.

Check unplugging (this is the can't unplug something that isn't plugged in rule):
	if the noun is not plugged in, say "It is already unplugged." instead.

Carry out unplugging (this is the basic unplugging rule):
	now the noun is not plugged in.

Report unplugging (this is the basic report unplugging rule):
	say "[if the actor is the player]You have pulled the plug on [the noun].[otherwise][The actor] unplugs [the noun].[end if]".

Check going when the player encloses something plugged in (called the item) (this is the can't go when carrying something plugged in rule):
	say "Not while [the item] you're carrying is still plugged in!" instead.

Check closing an open container (this is the can't close a container that holds something plugged in rule):
	if the noun encloses something plugged in (called the item), say "The cord running from [the item] inside [the noun] to the wall keeps you from closing [the noun]." instead.

Section 2 - Remote Controls

A remote control is a kind of thing.
A remote control button is a kind of thing.
A remote control has a remote control button called the main button.

Controlling relates one thing to another.
The verb to control (it controls, they control, it controlled, it is controlled, it is controlling) implies the controlling relation.

Broadcasting it to is an action applying to two things.
A rule for reaching inside while broadcasting: allow access.

Instead of pushing a remote control button (called the pushed button):
	say "You press [the noun].";
	repeat with the receiver running through the thing controlled by the holder of the button begin;
		try broadcasting the pushed button to the receiver;
	end repeat;

Switching it on with is an action applying to one thing and one carried thing.
Understand "turn on [something] with [something preferably held]" as switching it on with.
Understand "turn [something] on with [something preferably held]" as switching it on with.

Switching it off with is an action applying to one thing and one carried thing.
Understand "turn off [something] with [something preferably held]" as switching it off with.
Understand "turn [something] off with [something preferably held]" as switching it off with.

Carry out switching something on with something:
	try broadcasting the main button of the second noun to the noun.

Carry out switching something off with something:
	try broadcasting the main button of the second noun to the noun.


Chapter 3 - Game Objects

Section 1 - The Alarm Clock

The alarm clock is a pluggable device.
The clock can be beeping.
The clock can be blinking.
The alarm clock has a time called the clock time.
The alarm clock has a time called the alarm time.

Every turn:
	if the clock is plugged in and the clock was plugged in, change the clock time of the clock to one minute after the clock time of the clock;
	if the clock is plugged in and the clock is not blinking and the clock time of the clock is the alarm time of the clock, now the clock is beeping;
Every turn:
	if the clock is beeping and the clock is enclosed by the location of the player begin;
		say "Your alarm clock spits an irritating series of beeps. ";
	otherwise if the clock is beeping and the clock is in the same region as the player;
		say "Somewhere nearby, your alarm clock spits an irritating series of beeps. ";
	end if.

Instead of examining the clock:
	if the clock is plugged in, say "[if blinking][the clock time]... [the clock time]... [the clock time]... [otherwise]The clock reads [the clock time]. [end if]It is plugged in. ";
	if the clock is not plugged in, say "The clock's display is blank. It is not plugged in. ";
	say "There are buttons so you can set the clock to the right time, and set an alarm for when you want to wake up."

Carry out plugging the alarm clock:
	change the clock time to 12:00 am;
	change the alarm time to 12:00 am;
	now the clock is blinking.

Carry out unplugging the clock:
	try switching off the clock.

Understand "stop [the clock]" as switching off.

Instead of switching off the clock (this is the switching off the clock rule):
	if the clock is beeping begin;
		now clock is not beeping;
		say "The beeping stops.";
	otherwise if the clock is plugged in and the clock is not beeping;
		say "It is not beeping.";
	otherwise if the clock is not plugged in;
		say "It's not even plugged in!";
	end if.


Instead of switching on the clock (this is the switching on the clock rule):
	if the clock is plugged in, say "It is already on.";
	otherwise try plugging the clock.


Setting alarm is an action applying to one thing and one time.
Understand "set [something] for [a time]" as setting alarm.
Check setting alarm:
	if the noun is not the alarm clock, say "You can not set that for a time." instead;
	if the alarm clock is not plugged in, say "The clock is off." instead.
Carry out setting alarm: change the alarm time of the noun to the time understood.
Report setting alarm: say "Done."

Setting clock is an action applying to one thing and one time.
Understand "set [something] to [a time]" as setting clock.
Check setting clock:
	if the noun is not the alarm clock, say "You can not set that to a time." instead;
	if the alarm clock is not plugged in, say "The clock is off." instead.
Carry out setting clock:
	change the clock time of the noun to the time understood;
	change clock to not blinking.
Report setting clock: say "Done."

Section 2 - The Cell Phone

The cell phone is a device. Understand "telephone" as phone.
The phone can be ringing.
The phone is small.

Instead of inserting the cell phone into the toilet:
	if Rough Start is happening, say "That would almost literally be flushing your entire career.";
	otherwise continue the action.

To say the insistent phone message:
	say "It surely is your imagination, but the phone seems to ring even louder and more insistently."

Every turn:
	if the phone is ringing and the phone is enclosed by the location of the player begin;
		say "Your cell phone blares its tinny rendition of Beethoven's Ninth. ";
	otherwise if the phone is ringing and the phone is in the same region as the player;
		say "Somewhere nearby, your cell phone blares its tinny rendition of Beethoven's Ninth. ";
	end if.

Instead of going when the phone is ringing and the location encloses the phone, say the insistent phone message.

[remove built in answer behavior from play]
Understand the command "answer" as something new.
The block answering rule is not listed in any rulebook.

Answering is an action applying to one carried thing.
Understand "answer [something]" as answering.
Understand "answer" as answering.
Rule for supplying a missing noun while answering (this is the assume answering the phone rule): change the noun to the phone.

Check answering (this is the check answering rule):
	if the noun is nothing, say "hi." instead;
	if the noun is not the phone, say "[The noun] can not be answered." instead;
	if the phone is not ringing, say "It's not ringing." instead.

Carry out answering (this is the carry out answering rule):
	now the phone is not ringing.

Report answering (this is the report answering rule):
	if we have not answered the phone begin;
		say "It is Alexis, your secretary. 'Oh my god, Mr. V, where are you? It's [if it is before 7:00 am]almost 7 and the polls are about to[otherwise]after [the hours part of the time of day] and the polls are[end if] open and we're having problems in two precincts already! The power is out in the Southeast, and six poll workers called in sick in the Northwest! You need to take care of it right away! Right now! I can't believe you're still at home! Please leave right away! Oh my god there's my other line!' She hangs up. Your head hurts and you feel all bleary. You're having a hard time focusing.";
		if we have not examined the PDA begin;
			if it is before 7:00 am, now the right hand status line is "'almost 7'?";
			otherwise now the right hand status line is "'after [the hours part of the time of day]'?";
		end if;
	otherwise;
		say "It's Alexis again.[paragraph break][The blather corresponding to a location of (the location of the player) in the table of Alexis's phone blather]";
	end if.

Section 3 - The PDA

The PDA is a device.
The PDA can be chiming.
The PDA has a number called last read message. The last read message of the PDA is 0.
The PDA is small.

To decide which number is the number of emails:
	let the current count be 0;
	repeat through the Table of Emails begin;
		if the received entry is 1, increase the current count by 1;
	end repeat;
	decide on the current count.

To decide which number is the number of new emails:
	let the current count be 0;
	repeat through the Table of Emails begin;
		if the received entry is 1 and the read entry is 0, increase the current count by 1;
	end repeat;
	decide on the current count.

Before examining the email:
	if the PDA is not carried by the player begin;
		say "(first taking the PDA)";
		silently try taking the PDA;
		if the PDA is not carried by the player, stop the action;
	end if.

Instead of switching off the PDA, say "Not today."

Every turn:
if the PDA is touchable and the PDA is chiming, say "Your PDA chimes to indicate incoming e-mail. "

Table of Emails
Message Number		Received	Read	Time Received	Time Read	Sender			Subject				Body
1			1		0	1:00 am		a time		"Watergate, Abraham"	"too fun to speak of, almost"	"Jim-Jimmy-James! Great dinner, great wine, great company! Hope your wife wasn't too mad we kept you out so late. Take good care of us voters out there today, all right? -- Abe."
2			1		0	6:00 am		--		"honey"			"coming home early"		"Honey, I was able to book an earlier flight, so I'll be seeing you sooner than we thought. Good luck, today!!!! XOXOXO"
3			1		0	6:18 am		--		"a test emailer"		"just a test"			"more testing"
4			0		0	--		--		"emailer 2"		"test 2"				"even more testing"

The email is part of the PDA. Understand "message" as the email.

Instead of examining the email:
	repeat through the Table of Emails in time received order begin;
		if the read entry is 0 begin;
			say "(the oldest unread message)[paragraph break]";
			say "From: [the sender entry][line break]Subject: [the subject entry][line break][the body entry][paragraph break]";
			change the read entry to 1;
			change the time read entry to the time of day;
			now the PDA is not chiming;
			stop the action;
		end if;
	end repeat;
	repeat through the Table of Emails in time read order begin;
		say "(the least recently read message)[paragraph break]";
		say "From: [the sender entry][line break]Subject: [the subject entry][line break][the body entry][paragraph break]";
		change the time read entry to the time of day;
		now the PDA is not chiming;
		stop the action;
	end repeat;

Deleting is an action applying to one thing.
Understand "delete [the email]" as deleting.
Instead of deleting the email, say "Isn't there some kind of automatic archiver for that? The PC back at the office has all your email organized into folders, and the old ones go away on their own."

Instead of examining the PDA:
	say "It does a great many things, one of which you understand, and one of which you can manage most days. It tells time (currently [the time of day]) and it receives email ([number of emails in words] currently waiting, [number of new emails in words] new).";
	now the right hand status line is "[the time of day]!".

Section 4 - The Dresser

The dresser is an unsearchable supporter and scenery. The description is "A faux-antique four-drawer dresser[if the dresser supports something], on which sit[end if][if the dresser supports exactly one thing]s[end if][if the dresser supports something] [a list of the things supported by the dresser][end if]."

The first drawer is a part of the dresser.  It is a container and openable and closed.
Instead of opening or searching the first drawer, say "Women's underwear and pantyhose. You shut it quickly before you feel like a pervert!"

The second drawer is a part of the dresser.  It is a container and openable and closed. The second drawer contains two pairs of socks.
Instead of searching the second drawer, say "Men's socks. Rows and rows of black socks, all neatly rolled into balls."
After opening the second drawer, try searching the noun.
Instead of inserting something (called the item) into the second drawer:
	if the item is not a pair of socks begin;
		say "It's chock full of socks!";
	otherwise;
		continue the action;
	end if.
Instead of removing something from the second drawer when the second drawer contains exactly one thing, say "Your shoes fit you just fine. One pair will do."

The third drawer is a part of the dresser.  It is a container and openable and closed. The third drawer contains two shirts.
Instead of searching the third drawer, say "Men's shirts, fresh from the cleaner, all starched and folded."
After opening the third drawer, try searching the noun.
Instead of inserting something (called the item) into the third drawer:
	if the item is not a shirt begin;
		say "But that drawer is already so full of shirt.";
	otherwise;
		continue the action;
	end if.
Instead of removing something from the third drawer when the third drawer contains exactly one thing, say "They're all pretty much the same -- except that one you hid at the very bottom, and now's not the time."

The fourth drawer is a part of the dresser.  It is a container and openable and closed. The fourth drawer contains two pairs of pants.
Instead of searching the fourth drawer, say "Men's pants, fresh from the cleaner, folded neatly."
After opening the fourth drawer, try searching the noun.
Instead of inserting something (called the item) into the fourth drawer:
	if the item is not a pair of pants begin;
		say "You decide not to shove [the noun] into your pants.";
	otherwise;
		continue the action;
	end if.
Instead of removing something from the fourth drawer when the fourth drawer contains exactly one thing, say "Yes, yes. You wear the pants around here. We get it already."

Section 5 - The Toilet

The toilet is scenery and a container and openable and open. The carrying capacity of the toilet is 1.
An unsearchable supporter called the tank is part of the toilet. Understand "back of the toilet" as the tank.

After inserting something into the toilet:
	carry out the soaking activity with the noun;
	continue the action.

Flushing is an action applying to one thing. The flushing action has an object called the flushee.
Understand "flush [something]" as flushing.

Check inserting something into the toilet:
	if the noun is large, say "[The noun] will not fit into the toilet." instead.

Check flushing something:
	if the toilet is not in the location, say "That will be a little hard with no toilets around." instead.

Before flushing something:
	if toilet is in the location and the noun is not the toilet and the noun is not in the toilet begin;
		try inserting the noun into the toilet;
		if the noun is not in the toilet, stop the action;
	end if.

Carry out flushing something:
	if the toilet contains something begin;
		repeat with the flushed item running through the things contained by the toilet begin;
			now the flushee is the flushed item;
			if the flushed item is small, remove the flushed item from play;
		end repeat;
	end if.

Report flushing something:
	if the flushee is nothing, say "The water swirls, swirls, drains, refills." instead;
	if the flushee is in the toilet, say "The water swirls, swirls, pulling on [the flushee], but as it drains and refills, [the flushee] remains in place." instead;
	if the flushee is off-stage, say "The water swirls, [the flushee] twirls and slips out of sight as the water drains and refills. The toilet again holds only water."
		

Section 6 - The TV Remote

TV-remote is a remote control. The printed name of the TV-remote is "the remote control to the TV". Understand "control/remote" or "remote control" or "remote/control to the TV/television" or "remote control to the TV/television" or "TV/television remote" as the TV-remote. The description of the TV-remote is "It's kind of insultingly understandable. Power button. Channel up, channel down. Volume up, volume down.[if we have not examined the TV-remote] You feel certain you could have handled the HouseMaster Two Million model, but who has time to read an eighty-page manual?[end if]".

The power button, the channel up button, the channel down button, the volume up button, and the volume down button are remote control buttons and part of the TV-remote. The main button of the TV-remote is the power button.

Before pushing a remote control button (called the pushed button):
	if the player does not carry the TV-remote begin;
		say "(first taking the television remote)";
		silently try taking the TV-remote;
		if the player carries the TV-remote, continue the action;
	end if.

To say the defensive remote message:
	say "So many buttons... And where's that panel they're hidden behind? At first you were galled when the installers gave up and left you with the 'luddite special' remote, but you've mostly accepted it by now."

To say the resigned remote message:
	say "In truth, you are quite helpless without the remote."

Section 7 - The TV

The TV is a pluggable device. It is scenery and switched off. Understand "plasma/television" and "plasma television" as the TV.
The TV has a number called the volume. The volume of the TV is 3.
The TV has a number called the channel. The channel of the TV is 11.
The TV-remote controls the TV.

To say the mournful TV message:
	say "Alas, there are no TV's here at this time."

To say the volume relief message:
	say "Ahhhhh... thank god! You ears settle into a relatively quiet ringing spell."

Implied-remote-pushing something is an activity.

Rule for implied-remote-pushing something (called the implied button):
	if the TV is not in the location, say the mournful TV message instead;
	if the player does not hold the TV-remote, say the defensive remote message;
	if the player holds the TV-remote begin;
		say "(using the remote control)";
	otherwise if the location encloses the TV-remote;
		say "(first taking the television remote)";
		silently try taking the TV-remote;
	end if;
	if the player holds the TV-remote, try pushing the implied button; otherwise say the resigned remote message.

Carry out unplugging the TV: now the TV is switched off.

Instead of switching on the TV:
	if the TV is switched on, say "It's already on." instead;
	carry out the implied-remote-pushing activity with the power button.

Instead of switching off the TV:
	if the TV is switched off, say "It's already off." instead;
	carry out the implied-remote-pushing activity with the power button;

Changing volume up is an action applying to one thing.
Understand "turn up [the TV]" or "turn [the TV] up" or "turn [volume up]" or "turn [TV] volume up" as changing volume up.
Instead of changing volume up:
	carry out the implied-remote-pushing activity with the volume up button.

Changing volume down is an action applying to one thing.
Understand "turn down [the TV]" or "turn [the TV] down" or "turn [volume down]" or "turn [TV] volume down" as changing volume down.
Instead of changing volume down:
	carry out the implied-remote-pushing activity with the volume down button;
	if Rough Start is happening and the volume of the TV is 2 and the volume of the TV was 3 begin;
		say "[the volume relief message][paragraph break]The morning local news is on. You hate local news. Except for that profile they did on you a couple weeks ago. That was nice. But mostly you think local news rots. A too-handsome-to-be-true anchor is talking: 'In the predominantly African-American Northwest Precinct, as the first voters are lining up, we're already hearing complaints about problems...'";
		now the cell phone is ringing;
	end if.


Changing channel up is an action applying to nothing.
Understand "change channel up" or "change TV/television channel up" as changing channel up.
Instead of changing channel up:
	carry out the implied-remote-pushing activity with the channel up button.

Changing channel down is an action applying to nothing.
Understand "change channel down" or "change TV/television channel down" as changing channel down.
Instead of changing channel down:
	carry out the implied-remote-pushing activity with the channel down button.
			
Instead of broadcasting the power button to the TV:
	if the TV is not in the location or the TV is not plugged in begin;
		say "Nothing happens.";
	otherwise if the TV is switched off;
		now the TV is switched on;
		say "The television comes to life.";
	otherwise if the TV is switched on;
		now the TV is switched off;
		say "The television dies.";
		if Rough Start is happening and the volume of the TV was 3, say the volume relief message;
	end if.

Before pushing the volume up button:
	if the volume of the TV is 4, say "WHAT!?" instead;
	if the volume of the TV is 0, say "Silence is about as quiet as it gets." instead.

Instead of broadcasting the volume up button to the TV:
	if the TV is not in the location or the TV is not plugged in or the TV is switched off begin;
		say "Nothing happens.";
	otherwise;
		increase the volume of the TV by one;
		if the volume of the TV is 1, say "Now the television is at a 'Lawrence Welk' listening level.";
		if the volume of the TV is 2, say "Now the television is at a 'Law & Order' listening level.";
		if the volume of the TV is 3, say "Now the television is at a 'Top Gun' listening level.";
		if the volume of the TV is 4, say "Now the television is at a 'piss off the neighbors' level.";
	end if.

Instead of broadcasting the volume down button to the TV:
	if the TV is not in the location or the TV is not plugged in or the TV is switched off begin;
		say "Nothing happens.";
	otherwise;
		decrease the volume of the TV by one;
		if the volume of the TV is 0, say "Now television is silent.";
		if the volume of the TV is 1, say "Now the television is at a 'Lawrence Welk' listening level.";
		if the volume of the TV is 2, say "Now the television is at a 'Law & Order' listening level.";
		if the volume of the TV is 3, say "Now the television is at a 'Top Gun' listening level.";
	end if.

Instead of broadcasting the channel up button to the TV:
	if the TV is not in the location or the TV is not plugged in or the TV is switched off begin;
		say "Nothing happens.";
	otherwise;
		increase the channel of the TV by one;
		say "The television changes to channel [the channel of the TV].";
	end if.

Instead of broadcasting the channel down button to the TV:
	if the TV is not in the location or the TV is not plugged in or the TV is switched off begin;
		say "Nothing happens.";
	otherwise;
		decrease the channel of the TV by one;
		say "The television changes to channel [the channel of the TV].";
	end if.

To decide whether the TV is too loud:
	if the TV is not in the location, decide no;
	if the TV is not switched on, decide no;
	if Rough Start is happening and the volume of the TV is greater than 2, decide yes;
	if the volume of the TV is greater than 3, decide yes.
	
Every turn when the TV is too loud:
	if Rough Start is happening begin;
		if the volume of the TV is 3, say "Oh god! The volume! So loud! Your ears! Your headache!";
		otherwise say "Aaaaaaaargh!! This is causing a brain hemorrhage!";
	end if;

Taking the TV-remote is doing something possible when the TV is turned up.
Switching off the TV is doing something possible when the TV is turned up.
Pushing the power button is doing something possible when the TV is turned up.
Changing volume up is doing something possible when the TV is turned up.
Changing volume down is doing something possible when the TV is turned up.
Pushing the volume up button is doing something possible when the TV is turned up.
Pushing the volume down button is doing something possible when the TV is turned up.
Broadcasting is doing something possible when the TV is turned up.

Before doing anything when the TV is too loud:
	if we are not doing something possible when the TV is turned up,
		say "The TV is so loud you can't even think!" instead.

Instead of changing volume down the first time:
	say "You scramble across the remote control buttons in a frenzy to turn down the volume.";
	try pushing the volume up button.

Instead of changing volume down the second time:
	say "You steady your hands and muster all your concentration to the task at hand.";
	try pushing the volume down button.

Section 8 - The Car

The car is a vehicle.  The initial appearance of the car is "Your car, a beautiful new Lincoln, sits before you." Understand "Lincoln" as the car. The description of the car is "[if the player is not in the car]Very black, very shiny, very new, very very.[otherwise]Leather seats, wood trim, stylish controls, navigation system, and over half a dozen cup holders. This baby has it all.[end if]"

The GPS is part of the car. Understand "system" or "navigation" or "navigation system" as the GPS.
The description of the GPS is "[if the player is not in the car]You can't see much about it from outside the car.[otherwise]You love this thing. It's the most advanced on the market. With its realtime access to traffic data, it always knows the best routes to take. You won't even go anywhere anymore unless the destination is programmed in. And it always seems to know the places you need to get to. There they are on the screen.[end if]"

The screen is part of the GPS.
Instead of examining the screen:
	if the player is not in the car, say "You can't read it from outside the car." instead;
	say "The destinations listed on the screen are:[line break]";
	repeat through the Table of Driveable Places begin;
		say the Destination entry;
		say "[line break]";
	end repeat.


Instead of going anywhere by the car, say "Where do you want to drive to?"

Driving is an action applying to one topic.

Understand "drive to [text]" as driving.
[Understand "drive" as driving.]

Check driving:
	if the player is not in the car, say "You are not in the car." instead;
	if the topic understood is not a topic listed in the Table of Driveable Places, say "You can't off the top of your head recall how to drive there." instead;
	if the car is in the Room entry, say "You are already there." instead.

Carry out driving:
	if the topic understood is a topic listed in the Table of Driveable Places begin;
		move the car to the Room entry;
	end if.

Report driving:
	say "You pull off in the car, following the directions softly called out by the GPS as you go along. With little trouble, you pull up at the...";
	try looking.
[
Instead of driving when the topic understood is "":
	say "You'll have to specify where to drive."
]

Table of Driveable Places
Topic						Destination		Room
"home/driveway"					"Home"			Driveway
"se/southeast" or "se/southeast precinct"		"Southeast Precinct"	Southeast Precinct Parking Lot
"nw/northwest" or "nw/northwest precinct"	"Northwest Precinct"	Northwest Precinct Parking Lot


Chapter Three - Rules and Relationships


Chapter Four - The Player

Section 1 - Blurry Eyes

A person can be either clear-eyed or blurry-eyed.
A person is usually clear-eyed.

The blurry eye turn count is a number that varies.

Table of Blurry Eye Responses
Turn Count	Response
0		"You're having a hard time focusing on anything.[paragraph break]"
1		"You're really having a hard time focusing your eyes.[paragraph break]"
2		"Man, your eyes ache.[paragraph break]"
3		"This double vision is incredibly annoying, isn't it?[paragraph break]"
4		"Seriously, your eyes could use a good rubbing.[paragraph break]"

Eye rubbing is an action applying to nothing.
Understand "Rub eyes" as eye rubbing.

Carry out eye rubbing:
	if the actor is clear-eyed, say "Things don't improve much.";
	if the actor is blurry-eyed begin;
		say "Things swim into focus, although a mariachi band is still performing with a group of kettle drummers behind your temples.";
		now the actor is clear-eyed;
		try looking;
	end if.

Taking the phone is managing despite blurred vision.
Answering is managing despite blurred vision.
Eye rubbing is managing despite blurred vision.

Before doing anything when the player is blurry-eyed (this is the can't do much of anything with blurry eyes rule):
	if we are not managing despite blurred vision begin;
		say the response corresponding to a turn count of (the blurry eye turn count) in the Table of Blurry Eye Responses;
		if the blurry eye turn count is less than 4, change the blurry eye turn count to the blurry eye turn count plus 1;
		stop the action;
	end if.


Part III - The Game World

Chapter One - Items That Start the Game Offstage (Spoiler Alert!)

The offstage hamper is a container.

A pair of pants called a crumpled pair of slacks is in the hamper.  Understand "black" or "dress" or "pants" as the slacks. The description of the slacks is "Just your size, and pretty darn stylish, you don't mind saying."

A pair of underpants called a white boxers is in the offstage hamper. The description of the boxers is "Just your size, and pretty darn stylish, you don't mind saying."

A pair of socks called a balled up pair of black socks is in the offstage hamper. The description of the balled up pair of socks is "Just your size, and pretty darn stylish, you don't mind saying."

A coat called a tan sports coat is in the offstage hamper. The description of the coat is "Just your size, and pretty darn stylish, you don't mind saying."

The pair of black wingtips is a pair of shoes. Understand "shoes" as the wingtips. The description of the wingtips is "A man's black wingtips. Your size."

The woman's blouse is a shirt. The description of the blouse is "It is slinky and black and smells faintly of smoke and perfume."
Instead of wearing the blouse, say "Alas, it does not fit."

A shoe called a right shoe is a wearable thing. The description of the shoe is "It's a man's black wingtip, right. Your size. It looks oddly familiar."

After taking a shoe (this is the combine two shoes into a pair rule):
	if the player carries two shoes begin;
		remove the left shoe from play;
		remove the right shoe from play;
		now the player carries the wingtips;
	end if;
	continue the action.

Instead of wearing a shoe, say "Let's wait until you have its partner, too."

Chapter Two - James' House

The Home Region is a region.
The Bedroom, the Bathroom, the Kitchen, and the Living Room are electrified rooms in the Home Region.
The Driveway is in the Home Region.
The bathroom door is east of the the Bedroom and west of the Bathroom.  It is a door and scenery.
The bedroom door is south of the bedroom and north of the Living Room. It is a door and scenery.
The Kitchen is south of the Living Room.
The front door is west of the living room and east of the Driveway.  It is a door and scenery and closed and lockable.


Section 1 - The Bedroom

The description of the Bedroom is "It's a tasteful room, furnished straight out of the Pottery Barn catalogue. A nice, strong wooden bed with a simple but elegant headboard. A faux-antique four-drawer dresser. [if at least two wearable things are in the location or the clothes pile is in the location] Some clothes scattered about the room.[end if]".

The dresser is in the Bedroom.

The cell phone, the PDA, and the alarm clock are on the dresser.
The alarm clock is beeping. The cell phone is ringing. The PDA is chiming.
The alarm clock has clock time 4:48 AM. The alarm clock has alarm time 4:30 AM.

A photo in a frame is on the dresser. The description of the photo is "Your heart warms to see a photo of you standing at the rim of the Grand Canyon with a lovely woman and a handsome young man of around twenty. Ah, yes. The wife and son. You smile. Deep in the back of your mind, an unexplained feeling of guilt leaks in."

A bed is in the Bedroom. It is a supporter and enterable and scenery.

Instead of looking under the bed for the first time:
	say "A woman's blouse lies crumpled under there. [the description of the blouse] You pick it up.";
	now the player carries the woman's blouse.

Instead of putting something under (this is the can't put something under the bed rule):
	if the second noun is the bed, say "Not when you're sober!";
	otherwise continue the action.

The clothes pile is in the Bedroom. It is scenery. The description of the pile is "A crumpled pair of black dress slacks. White boxers. A balled-up pair of black socks. A tan ports coat. All just your size, and pretty darn stylish, you don't mind saying."

After examining the pile:
	now everything in the offstage hamper is in the location;
	remove the pile from play.

Instead of searching the pile, try examining the pile.

After taking the pile:
	consider the standard report taking rule;
	now the player carries everything in the offstage hamper;
	remove the pile from play.

Section 2 - The Bathroom

The description of the Bathroom is "You are in your bathroom. It appears to have been recently remodeled, at great expense, in tropical shades of pink and lime that hurt your eyes. Even the toilet is lime-green porcelain. The mirror is huge. The shower is all pink marble and opaque glass. [if the tank supports something]On the back of the toilet [end if][if the tank supports one thing]sits[end if][if the tank supports more than one thing]sit[end if][if the tank supports something] [a list of things on the tank].[end if]"

In the Bathroom is a mirror. It is scenery. The description of the mirror is "You recoil. My god, you look terrible. Your hair is greasy and tousled, you are unshaven, your eyes are bloodshot and glassy, your cheeks puffy. What the hell happened to you? You normally look so good for forty-seven, giving off that sort of Ward Cleaver handsome dad, man's man vibe."

Understand "look in [the mirror]" as examining.

The toilet is in the Bathroom.

On the tank is a shoe called a left shoe. The description of the shoe is "It's a man's black wingtip, left. Your size. It looks oddly familiar."

In the Bathroom is a shower. It is a container and enterable and scenery.

Section 3 - The Living Room

The description of the Living Room is "You are in your living room, which like the bedroom, could have come straight from the Pottery Barn catalogue. There is an immense plasma television, a nice black leather couch, a rug that looks Turkish but probably isn't, a wood and glass coffee table. The kitchen is to the south, and the front door is to the west."

A couch is in the Living Room. It is a supporter and enterable and scenery.

Instead of looking under the couch for the first time:
	say "You find a man's black wingtip, right. Your size. It looks oddly familiar.[run paragraph on]";
	now the right shoe is in the location;
	silently try taking the right shoe;
	if the player carries the right shoe or the player carries the wingtips, say " You pick it up."; otherwise say "[paragraph break]".

A rug is in the Living Room. It is scenery.

A coffee table is in the Living Room. It is an unsearchable supporter and scenery. Understand "glass" and "wood" as the coffee table.

The TV-remote is on the coffee table.

The TV is in the Living Room.

Section 4 - The Kitchentest getup

The description of the Kitchen is  "Hello Kitchen."

Section 5 - The Driveway

The description of the Driveway is "You stand in your driveway. It's incredibly bright out here. Your head is KILLING you."

The house is in the Driveway. It is scenery.

The car is in the Driveway.


Chapter Two - The Northwest Precinct

The Northwest Precinct is a region.
The Northwest Precinct Parking lot is in the Northwest Precinct.  

Chapter Three - The Souteast Precinct

The Southeast Precinct is a region.
The Southeast Precinct Parking lot is in the Southeast Precinct.  

Part III - People


Chapter One - The Player

Definition: a person is dressed enough if he wears pants and he wears a shirt or he wears pants and he wears a coat.
Definition: a person is going commando if he is dressed enough and he does not wear underpants.
Definition: a person is half-dressed upper if he wears exactly 0 pants and he wears a shirt or he wears exactly 0 pants and he wears a coat.
Definition: a person is half-dressed lower if he wears pants and he wears exactly 0 shirts or he wears pants and he wears exactly 0 coats.
Definition: a person is half-dressed if he is half-dressed lower or he is half-dressed upper.
Definition: a person is practically naked if he wears exactly one thing which is clothing.
Definition: a person is naked if he wears exactly zero things which are clothing.

Instead of going west in the Living Room (this is the can't leave when you're not dressed rule):
	if the front door is closed, continue the action;
	if the player is going commando begin;
		say "Going commando, eh? Interesting choice ... but hey, your call.";
		continue the action;
	end if;
	if the player is dressed enough begin;
		continue the action;
	end if;
	if the player is half-dressed, say "Are you crazy? You're only half-dressed." instead;
	if the player wears underwear and the player does not wear pants, say "Are you crazy? You'll be fired if you show up to work in only your underwear!" instead;
	if the player is practically naked, say "You're practically naked." instead;
	if the player is naked, say "Are you crazy? You're naked!" instead;

Instead of taking off pants:
	if the player is not in the Home Region or the player is in the Driveway, say "You made it out of the house with clothes on.  Let's keep them that way."

Instead of taking off shirt:
	if the player is not in the Home Region or the player is in the Driveway, say "You made it out of the house with clothes on.  Let's keep them that way."


Chapter Two - Alexis

Table of Alexis's Phone Blather
Location		Blather
Bedroom	"'Oh my god, Mr. V! What are you still doing home??!! Please get to those precincts now!'"
Bathroom	"'Oh my god, Mr. V! You don't have time for a shower! Please get to those precincts now!'"
Living Room	"'Oh my god, Mr. V! You don't have time to watch TV! Please get to those precincts now!'"
Kitchen		"'Oh my god, Mr. V! You don't have time for breakfast! Please get to those precincts now!'"

Entering the shower is something Alexis interrupts.
Pushing the channel up button is something Alexis interrupts.
Pushing the channel down button is something Alexis interrupts.
Examining the email more than one time is something Alexis interrupts.

Going south in the Kitchen is something Alexis reacts to.

Instead of something Alexis interrupts (this is the Alexis stopping you rule):
	if the phone is not ringing begin;
		say "You are stopped by the sound of your phone starting to ring.";
		now the phone is ringing;
	otherwise;
		say the insistent phone message;
	end if.

After something Alexis reacts to (this is the Alexis scolding you rule):
	if the phone is not ringing begin;
		say "Immediately your phone starts to ring.";
		now the phone is ringing;
	end if;
	continue the action.

The Alexis stopping you rule is listed first in the instead rulebook.
The Alexis scolding you rule is listed first in the after rulebook.


Part IV - The Story

Chapter One - The Beginning of Time

The time of day is 6:48 am.
The player is on the bed.
The player is blurry-eyed.

Chapter Two - Rough Start

Rough Start is a scene. Rough Start begins when play begins.

When Rough Start begins:
	change the right hand status line to "[the clock time of the alarm clock]";
	say "You are James Hanson Vandervliet III, elections chair of a swing county in a swing state in the most hotly contested presidential election in American history. You are awakened by a cacaphony of noises: Your cell phone blares its tinny rendition of Beethoven's Ninth. Your PDA chimes to indicate incoming e-mail. Your alarm clock spits an irritating series of beeps. You have the feeling these noises have been going on for a while, though the clock reads only 4:48. Everybody must be getting an early start, as should you. The polls open at 7:00."

Rough Start ends when the player is not in the Home Region.

Chapter Three - Game Over

When Rough Start ends, end the game saying "You have reached the edge of the game universe."

Part VI - Misc

test GetUp with " rub eyes / answer phone / stop clock / read pda / read email / get up "

test GetClothes with " open second drawer / open third drawer / open fourth drawer / get socks from second drawer / get shirt from third drawer / get pants from fourth drawer / e / get shoe / w / x clothes / get coat and boxers / s / l under couch ".
test WearClothes with " open front door / w / wear socks / w / remove boxers / wear pants / w / wear shirt / wear coat / w ".
test GetDressed with " test GetClothes / test WearClothes ".

test clock with "look at clock / unplug clock / look at clock / unplug clock / set clock to 10 am / set alarm for 10:03 am / plug clock / look at clock / plug clock / set clock to 10:00 am / set alarm for 10:03 am / look at clock / stop alarm".

test dresserAppearance with " l at dresser / get all but photo from dresser / l at dresser ".
test dresserOpen with " open first drawer / open second drawer / open third drawer / open fourth drawer ".
test dresserSearch with " search first drawer / search second drawer / search third drawer / search fourth drawer ".
test dresserGet with " get all from second drawer / get shirt from third drawer / get pants from fourth drawer ".
test dresserPut with " put phone in first drawer / put phone in second drawer / put phone in third drawer / put phone in fourth drawer ".
test dresser with " test dresserAppearance / test dresserOpen / test dresserSearch / test dresserGet / test dresserGet / test dresserPut ".

test TVPower with " turn on TV / turn off TV / press power button / g ".
test TVVolume with " turn volume down / turn TV volume up / turn TV down / turn up TV / press volume up button / press volume down button ".
test TVChannel with " change channel down / change TV channel up / press channel up button / press channel down button ".
test TVFunctions with " test TVPower / test TVVolume / test TVChannel / turn TV on / test TVVolume / test TVChannel ".
test TV with " test TVFunctions / n / test TVFunctions / drop remote / test  TVFunctions / drop remote / s / test TVFunctions ".

The player carries a player's holdall called a satchel. The description of the satchel is "It's European!"
A hat called a blue hat is in the satchel.
A skullcap called a toboggan is in the satchel.
A sweater called a sweater is in the satchel.